/*********************************************************************************************************************************/

/*********** SULLIVAN HEALTH EXPECTANCY USING AN UNABRIDGED LIFE TABLE : EXAMPLE 1 ************/

/*********************************************************************************************************************************/

/******** Calculation of the life table and life expectancy ********/

GET DATA /TYPE=XLS

   /FILE='_____\input_examples.xls'



      /* Specify the directory of the input data */

   /SHEET=name 'input_example1'

   /CELLRANGE=full

   /READNAMES=on .

COMPUTE mx = Dx / Px .

COMPUTE qx = mx/(1+(0.5*mx)) .

IF (x = 0) qx = 1-(1-((Dx-Dx2)/Px1))*(1-(Dx2/B)) .

IF (x = 85) qx = $SYSMIS .

IF (x = 0) lx = 100000 .

IF (x > 0) lx = lag(lx)*(1-lag(qx)) .

SORT CASES BY x (D) .

COMPUTE LLx = (lx+lag(lx))/2 .

IF (x = 0) LLx = 0.2*lx+0.8*lag(lx) .

IF (x = 85) LLx = lx/mx .

DO IF x = 85 .

COMPUTE Tx = LLx .

ELSE .

COMPUTE Tx  = lag(Tx) + LLx .

END IF.

SORT CASES BY x (A) .

COMPUTE ex = Tx/lx .

FORMAT pix (F5.3) mx qx (F8.6) ex (F4.1) .

SAVE OUTFILE='_____\example1.sav'


        /* Specify the directory of the output data */

   /KEEP=x Px Dx mx qx lx LLx Tx ex pix /COMPRESSED .

/******** Calculation of Disability-Free Life Expectancy (DFLE) ********/

GET FILE='_____\example1.sav' .



         /* Specify the directory of the output data */

COMPUTE LLx_disafr = LLx*(1-pix) .

SORT CASES BY x (D) .

DO IF x = 85 .

COMPUTE Tx_disafr = LLx_disafr .

ELSE .

COMPUTE Tx_disafr  = lag(Tx_disafr) + LLx_disafr .

END IF .

SORT CASES BY x (A) .

COMPUTE DFLEx = Tx_disafr/lx .

COMPUTE percDFLEx = 100*(DFLEx/ex) .

FORMAT DFLEx percDFLEx (F4.1) .

VARIABLE LABELS x 'Age' 



      Px 'Mid-year population' 



      Dx 'No. deaths' 


  
      mx 'Central Death rate'


  
      qx 'Conditional probability of death'


  
      lx 'Numbers surviving to age x'


  
      LLx 'Person years lived at age x'


  
      Tx 'Total number of years lived from age x'


  
      ex 'Total Life Expectancy'


  
      pix 'Proportion with disability'


  
      LLx_disafr 'Person years lived without disability at age x'


  
      Tx_disafr 'Total years lived without disability from age x'


  
      DFLEx 'Disability-free life expectancy'


  
      percDFLEx 'Proportion of life spent disability-free' .

SAVE OUTFILE='_____\example1.sav'


          /* Specify the directory of the output data */



   /COMPRESSED .

/*********************************************************************************************************************************/

/*********** SULLIVAN HEALTH EXPECTANCY USING AN UNABRIDGED LIFE TABLE : EXAMPLE 2 ************/

/*********************************************************************************************************************************/

/******** Calculation of the life table and life expectancy ********/

GET FILE='_____\example1.sav' .



          /* Specify the directory of the output data */

IF (x = 0) 




agegr = 0 .

IF (x = 1 or x = 2 or x = 3 or x = 4) 

agegr = 1 .

IF (x = 5 or x = 6 or x = 7 or x = 8 or x = 9) 
agegr = 5 .

IF (x = 10 or x = 11 or x = 12 or x = 13 or x = 14) agegr = 10 .

IF (x = 15 or x = 16 or x = 17 or x = 18 or x = 19) agegr = 15 .

IF (x = 20 or x = 21 or x = 22 or x = 23 or x = 24) agegr = 20 .

IF (x = 25 or x = 26 or x = 27 or x = 28 or x = 29) agegr = 25 .

IF (x = 30 or x = 31 or x = 32 or x = 33 or x = 34) agegr = 30 .

IF (x = 35 or x = 36 or x = 37 or x = 38 or x = 39) agegr = 35 .

IF (x = 40 or x = 41 or x = 42 or x = 43 or x = 44) agegr = 40 .

IF (x = 45 or x = 46 or x = 47 or x = 48 or x = 49) agegr = 45 .

IF (x = 50 or x = 51 or x = 52 or x = 53 or x = 54) agegr = 50 .

IF (x = 55 or x = 56 or x = 57 or x = 58 or x = 59) agegr = 55 .

IF (x = 60 or x = 61 or x = 62 or x = 63 or x = 64) agegr = 60 .

IF (x = 65 or x = 66 or x = 67 or x = 68 or x = 69) agegr = 65 .

IF (x = 70 or x = 71 or x = 72 or x = 73 or x = 74) agegr = 70 .

IF (x = 75 or x = 76 or x = 77 or x = 78 or x = 79) agegr = 75 .

IF (x = 80 or x = 81 or x = 82 or x = 83 or x = 84) agegr = 80 .

IF (x = 85) 




agegr = 85 .

FORMAT agegr (F3.0) .

VALUE LABELS agegr 0 "0"  1 "1-4"  5 "5-9"  10 "10-14"  15 "15-19"  20 "20-24"  25 "25-29" 



          30 "30-34"  35 "35-39"  40 "40-44"  45 "45-49"  50 "50-54"  55 "55-59"  60 "60-64"



          65 "65-69'" 70 "70-74"  75 "75-79"  80 "80-84"  85 "85+" .

AGGREGATE 

   /OUTFILE '_____\example2.sav'



       /* Specify the directory of the output data */

   /BREAK agegr

   /x_a = FIRST(x) / pix_a = FIRST(pix) / lx_a = FIRST(lx) / nLx = SUM(LLx) .

GET FILE='_____\example2.sav'



       /* Specify the directory of the output data */ 

   /RENAME x_a = x pix_a = pix lx_a = lx .

SORT CASES BY agegr (D) .

DO IF agegr = 85 .

COMPUTE Tx = nLx .

ELSE .

COMPUTE Tx  = lag(Tx) + nLx .

END IF.

SORT CASES BY agegr (A) .

COMPUTE ex = Tx/lx .

FORMAT ex (F4.1) .

SAVE OUTFILE='_____\example2.sav'


        /* Specify the directory of the output data */ 


   /KEEP=x agegr lx nLx Tx ex pix /COMPRESSED .

/******** Calculation of Disability-Free Life Expectancy (DFLE) ********/

GET FILE='_____\example2.sav' .



       /* Specify the directory of the output data */ 

COMPUTE nLx_disafr = nLx*(1-pix) .

SORT CASES BY agegr (D) .

DO IF agegr = 85 .

COMPUTE Tx_disafr = nLx_disafr .

ELSE .

COMPUTE Tx_disafr  = lag(Tx_disafr) + nLx_disafr .

END IF .

SORT CASES BY agegr (A) .

COMPUTE DFLEx = Tx_disafr/lx .

COMPUTE percDFLEx = 100*(DFLEx/ex) .

FORMAT DFLEx percDFLEx (F4.1) .

VARIABLE LABELS x 'Age at start of interval' 



      agegr 'Age group'


  
      nLx 'Person years lived in age interval'


  
      Tx 'Total number of years lived from age x'


  
      ex 'Total Life Expectancy'


  
      pix 'Proportion with disability'


  
      nLx_disafr 'Person years lived without disability in age interval'


  
      Tx_disafr 'Total years lived without disability from age x'


  
      DFLEx 'Disability-free life expectancy'


  
      percDFLEx 'Proportion of life spent disability-free' .

SAVE OUTFILE='_____\example2.sav'


        /* Specify the directory of the output data */


   /COMPRESSED .

/*******************************************************************************************************************************/

/************ SULLIVAN HEALTH EXPECTANCY USING AN ABRIDGED LIFE TABLE : EXAMPLE 3 *************/

/*******************************************************************************************************************************/

/******** Calculation of the life table and life expectancy ********/

GET DATA /TYPE=XLS

   /FILE='_____\input_examples.xls'



        /* Specify the directory of the input data */

   /SHEET=name 'input_example1'

   /CELLRANGE=full

   /READNAMES=on .

IF (x = 0) 




agegr = 0 .

IF (x = 1 or x = 2 or x = 3 or x = 4) 

agegr = 1 .

IF (x = 5 or x = 6 or x = 7 or x = 8 or x = 9) 
agegr = 5 .

IF (x = 10 or x = 11 or x = 12 or x = 13 or x = 14) agegr = 10 .

IF (x = 15 or x = 16 or x = 17 or x = 18 or x = 19) agegr = 15 .

IF (x = 20 or x = 21 or x = 22 or x = 23 or x = 24) agegr = 20 .

IF (x = 25 or x = 26 or x = 27 or x = 28 or x = 29) agegr = 25 .

IF (x = 30 or x = 31 or x = 32 or x = 33 or x = 34) agegr = 30 .

IF (x = 35 or x = 36 or x = 37 or x = 38 or x = 39) agegr = 35 .

IF (x = 40 or x = 41 or x = 42 or x = 43 or x = 44) agegr = 40 .

IF (x = 45 or x = 46 or x = 47 or x = 48 or x = 49) agegr = 45 .

IF (x = 50 or x = 51 or x = 52 or x = 53 or x = 54) agegr = 50 .

IF (x = 55 or x = 56 or x = 57 or x = 58 or x = 59) agegr = 55 .

IF (x = 60 or x = 61 or x = 62 or x = 63 or x = 64) agegr = 60 .

IF (x = 65 or x = 66 or x = 67 or x = 68 or x = 69) agegr = 65 .

IF (x = 70 or x = 71 or x = 72 or x = 73 or x = 74) agegr = 70 .

IF (x = 75 or x = 76 or x = 77 or x = 78 or x = 79) agegr = 75 .

IF (x = 80 or x = 81 or x = 82 or x = 83 or x = 84) agegr = 80 .

IF (x = 85) 




agegr = 85 .

FORMAT agegr (F3.0) .

VALUE LABELS agegr 0 "0"  1 "1-4"  5 "5-9"  10 "10-14"  15 "15-19"  20 "20-24"  25 "25-29" 



          30 "30-34"  35 "35-39"  40 "40-44"  45 "45-49"  50 "50-54"  55 "55-59"  60 "60-64"



          65 "65-69'" 70 "70-74"  75 "75-79"  80 "80-84"  85 "85+" .

AGGREGATE 

   /OUTFILE '_____\example3.sav'


                   /* Specify the directory of the output data */

   /BREAK agegr

   /x_a = FIRST(x) / pix_a = FIRST(pix) / Px1_a = FIRST(Px1) / Dx2_a = FIRST(Dx2) / B_a = FIRST(B) / Px_a=SUM(Px) / Dx_a = SUM(Dx) .

GET FILE='_____\example3.sav'



       /* Specify the directory of the output data */ 

   /RENAME x_a = x pix_a = pix Px1_a = Px1 Dx2_a = Dx2  B_a = B Px_a = Px Dx_a = Dx .

COMPUTE nmx = Dx / Px .

COMPUTE ax = 0.5 .

COMPUTE nqx = (5*nmx)/(1+((1-ax)*5*nmx)) .

IF (agegr = 0) nqx = 1-(1-((Dx-Dx2)/Px1))*(1-(Dx2/B)) .

IF (agegr = 1) nqx = (4*nmx)/(1+((1-ax)*4*nmx)) . 

IF (agegr = 85) nqx = $SYSMIS .

IF (agegr = 0) lx = 100000 .

IF (agegr > 0) lx = lag(lx)*(1-lag(nqx)) .

SORT CASES BY agegr (D) .

COMPUTE nLx = ((lx*5*ax)+(lag(lx)*5*(1-ax))) .

IF (agegr = 0) nLx = 0.2*lx+0.8*lag(lx) .

IF (agegr = 1) nLx = ((lx*4*ax)+(lag(lx)*4*(1-ax))) .

IF (agegr = 85) nLx = lx/nmx .

DO IF agegr = 85 .

COMPUTE Tx = nLx .

ELSE .

COMPUTE Tx  = lag(Tx) + nLx .

END IF.

SORT CASES BY agegr (A) .

COMPUTE ex = Tx/lx .

FORMAT pix (F5.3) Px (F8.1) Dx (F6.0) ax (F3.1) nmx (F8.6) nqx (F10.8) lx nLx Tx (F9.1) ex (F4.1) .

SAVE OUTFILE='_____\example3.sav'


       /* Specify the directory of the output data */

   /KEEP=x agegr Px Dx nmx ax nqx lx nLx Tx ex pix /COMPRESSED .

/******** Calculation of Disability-Free Life Expectancy (DFLE) ********/

GET FILE='_____\example3.sav' .



       /* Specify the directory of the output data */

COMPUTE nLx_disafr = nLx*(1-pix) .

SORT CASES BY agegr (D) .

DO IF agegr = 85 .

COMPUTE Tx_disafr = nLx_disafr .

ELSE .

COMPUTE Tx_disafr  = lag(Tx_disafr) + nLx_disafr .

END IF .

SORT CASES BY agegr (A) .

COMPUTE DFLEx = Tx_disafr/lx .

COMPUTE percDFLEx = 100*(DFLEx/ex) .

EXECUTE .

FORMAT nLx_disafr Tx_disafr (F9.1) DFLEx percDFLEx (F4.1) .

VARIABLE LABELS x 'Age at start of interval' 



      agegr 'Age group'


  
      Px 'Mid-year population'


  
      Dx 'No. deaths'


  
      nmx 'Central Death rate'


  
      nqx 'Conditional probability of death in age interval'


  
      lx 'Numbers surviving to age x'


  
      nLx 'Person years lived in age interval'


  
      Tx 'Total number of years lived from age x'


  
      ex 'Total Life Expectancy'


  
      pix 'Proportion with disability'


  
      nLx_disafr 'Person years lived without disability in age interval'


  
      Tx_disafr 'Total years lived without disability from age x'


  
      DFLEx 'Disability-free life expectancy'


  
      percDFLEx 'Proportion of life spent disability-free' .

SAVE OUTFILE='_____\example3.sav'


       /* Specify the directory of the output data */

   /COMPRESSED .

/********************************************************************************************************************************/

/************* THE STANDARD ERROR OF THE SULLIVAN HEALTH EXPECTANCY : EXAMPLE 4 ***************/

/********************************************************************************************************************************/

/******** Approximate standard errors ignoring the variance of the mortality rates ********/

GET DATA /TYPE=XLS

   /FILE='_____\input_examples.xls'



       /* Specify the directory of the input data */

   /SHEET=name 'input_example4'

   /CELLRANGE=full

   /READNAMES=on .

MATCH FILES /FILE=*

   /FILE='_____\example3.sav'



       /* Specify the directory of the output data */

   /BY agegr.

COMPUTE S2_pix = (pix*(1-pix))/Nx .

COMPUTE L2S2_pix = (nLx**2)*S2_pix .

SORT CASES BY agegr (D) .

DO IF agegr = 85 .

COMPUTE T_L2S2_pix = L2S2_pix .

ELSE .

COMPUTE T_L2S2_pix  = lag(T_L2S2_pix) + L2S2_pix .

END IF.

SORT CASES BY agegr (A) .

COMPUTE S2_DFLEx = T_L2S2_pix/(lx**2) .

COMPUTE S_DFLEx = sqrt(S2_DFLEx) .

EXECUTE .

FORMAT S2_pix (F8.6) L2S2_pix T_L2S2_pix (F10.0) S2_DFLEx (F7.5) S_DFLEx (F5.3) .

VARIABLE LABELS Nx 'Number in survey in age interval'


  
      S2_pix 'Variance of prevalence disability-free'


  
      S2_DFLEx 'Variance of DFLEx'

      
                  S_DFLEx 'Standard error of DFLEx' .

SAVE OUTFILE='_____\example4A.sav'


       /* Specify the directory of the output data */

   /KEEP=x agegr ax Dx nqx lx nLx ex pix nLx_disafr Tx_disafr DFLEx Nx S2_pix L2S2_pix T_L2S2_pix S2_DFLEx S_DFLEx / COMPRESSED .

/******** Standard errors taking into accout the variance of the mortality rates ********/

GET FILE='_____\example4A.sav'



       /* Specify the directory of the output data */ 

   /RENAME S2_DFLEx = S2_DFLEx_1 .

COMPUTE S2_qx = ((nqx**2)*(1-nqx))/Dx .

IF (agegr = 85) S2_qx = 0 .

SORT CASES BY agegr (D) .

COMPUTE y = (((1-ax)*5*(1-pix))+lag(DFLEx)) .

IF (agegr = 0) y = (((1-ax)*(1-pix))+lag(DFLEx)) .

IF (agegr = 1) y = (((1-ax)*4*(1-pix))+lag(DFLEx)) .

IF (agegr = 85) y = 0 .

COMPUTE z = ((y**2)*(lx**2)*(S2_qx)) .

SORT CASES BY agegr (D) .

DO IF agegr = 85 .

COMPUTE T_z = z .

ELSE .

COMPUTE T_z  = lag(T_z) + z .

END IF.

SORT CASES BY agegr (A) .

COMPUTE S2_DFLEx_2 = T_z/(lx**2) .

COMPUTE S2_DFLEx = S2_DFLEx_1+S2_DFLEx_2 .

FORMAT S2_DFLEx_1 (F7.5) S2_qx (F10.8) y (F7.4) z T_z (F12.3) S2_DFLEx_2 S2_DFLEx (F7.5) .

VARIABLE LABELS S2_qx 'Variance of probability of death'


  
      S2_DFLEx_1 'Variance of DFLEx (due to prevalence)'


  
      S2_DFLEx_2 'Variance of DFLEx (due to mortality)'


  
      S2_DFLEx 'Total variance of DFLEx' .

SAVE OUTFILE='_____\example4B.sav'


       /* Specify the directory of the output data */

   /DROP = Nx nLx ex nLx_disafr Tx_disafr S2_pix L2S2_pix T_L2S2_pix S_DFLEx /COMPRESSED .

/********************************************************************************************************************************/

/*********** TESTING THE EQUALITY OF TWO SULLIVAN HEALTH EXPECTANCIES : EXAMPLE 5 *************/

/********************************************************************************************************************************/

GET DATA /TYPE=XLS

   /FILE='_____\input_examples.xls'



       /* Specify the directory of the input data */

   /SHEET=name 'input_example5'

   /CELLRANGE=full

   /READNAMES=on .

COMPUTE x = agegr .

COMPUTE diff_DFLE = DFLEf-DFLEm .

COMPUTE S_diff_DFLE = S_DFLEf+S_DFLEm .

COMPUTE z = diff_DFLE/S_diff_DFLE .

COMPUTE pvalue = 2*(1-CDFNORM(z)).

STRING p (A6) .

IF (pvalue >0.20) p=">0.20" .

IF (pvalue <0.20) p="<0.20" .

IF (pvalue <0.10) p="<0.10" .

IF (pvalue <0.05) p="<0.05" .

IF (pvalue <0.02) p="<0.02" .

IF (pvalue <0.01) p="<0.01" .

IF (pvalue <0.002) p="<0.002" .

IF (pvalue <0.001) p="<0.001" .

FORMAT x (F3.0) DFLEf DFLEm (F4.1) S_DFLEf S_DFLEm diff_DFLE S_diff_DFLE z (F4.2) .

VALUE LABELS agegr 0 "0"  1 "1-4"  5 "5-9"  10 "10-14"  15 "15-19"  20 "20-24"  25 "25-29" 



          30 "30-34"  35 "35-39"  40 "40-44"  45 "45-49"  50 "50-54"  55 "55-59"  60 "60-64"



          65 "65-69'" 70 "70-74"  75 "75-79"  80 "80-84"  85 "85+" .

VARIABLE LABELS x 'Age at start of interval'


  
      agegr 'Age group'


  
      DFLEf 'Disability-free life expectancy females'

      

      S_DFLEf 'Standard error of DFLE females'

      

      DFLEm 'Disability-free life expectancy males'

      

      S_DFLEm 'Standard error of DFLE males'

      

      diff_DFLE 'Difference in DFLE between males and females'

      

      S_diff_DFLE 'Approximate standard error of difference in DFLE between males and females'


 
      z 'z statistic'


  
      p 'p value' .

SAVE OUTFILE='_____\example5.sav'


       /* Specify the directory of the output data */

   /KEEP=x agegr DFLEf S_DFLEf DFLEm S_DFLEm diff_DFLE S_diff_DFLE z p /COMPRESSED .

/********************************************************************************************************************************************/

/** SULLIVAN HEALTH EXPECTANCY USING SEPARATE DATA SOURCES FOR INSTITUTIONALISED : EXAMPLE 6 **/

/********************************************************************************************************************************************/

/******** Calculation of Disability-Free Life Expectancy (DFLE) ********/

GET DATA /TYPE=XLS

   /FILE='_____\input_examples.xls'



       /* Specify the directory of the input data */

   /SHEET=name 'input_example6'

   /CELLRANGE=full

   /READNAMES=on .

MATCH FILES /FILE=*

   /FILE='_____\example3.sav'



       /* Specify the directory of the output data */

   /BY agegr .

COMPUTE pix_total = ((1-Ix)*(pix))+Ix .

COMPUTE nLx_disafr_total=nLx*(1-pix_total) .

SORT CASES BY agegr (D) .

DO IF agegr = 85 .

COMPUTE Tx_disafr_total = nLx_disafr_total .

ELSE .

COMPUTE Tx_disafr_total  = lag(Tx_disafr_total) + nLx_disafr_total .

END IF.

SORT CASES BY agegr (A) .

COMPUTE DFLEx_total = Tx_disafr_total/lx .

EXECUTE .

FORMAT Ix pix_total (F5.3) nLx_disafr_total Tx_disafr_total (F9.1) DFLEx_total (F4.1) .

VARIABLE LABELS Ix 'Proportion in institutions'


  
      pix_total 'Proportion of age group (total) with disability'


  
      nLx_disafr_total 'Person years lived without disability in age interval'



      Tx_disafr_total 'Total years lived without disability from age x'


  
      DFLEx 'Disability-free life expectancy (excluding inst)'


  
      DFLEx_total 'Disability-free life expectancy (including inst)' .

SAVE OUTFILE='_____\example6A.sav'


       /* Specify the directory of the output data */

   /KEEP=x agegr lx nLx ex pix Ix pix_total nLx_disafr_total Tx_disafr_total DFLEx_total DFLEx /COMPRESSED .

/* Approximate standard errors ignoring the variance of the mortality rates */

GET DATA /TYPE=XLS

   /FILE='_____\input_examples.xls'


                   /* Specify the directory of the input data */

   /SHEET=name 'input_example4'

   /CELLRANGE=full

   /READNAMES=on .

MATCH FILES /FILE=*

   /FILE='_____\example6A.sav'



       /* Specify the directory of the output data */

   /BY agegr .

COMPUTE S2_pix_total = (1-Ix)*(1-Ix)*pix_total*(1-pix_total)/Nx .

COMPUTE L2S2_pix_total=(nLx**2)*S2_pix_total .

SORT CASES BY agegr (D) .

DO IF agegr = 85 .

COMPUTE T_L2S2_pix_total = L2S2_pix_total .

ELSE .

COMPUTE T_L2S2_pix_total  = lag(T_L2S2_pix_total) + L2S2_pix_total .

END IF.

SORT CASES BY agegr (A) .

COMPUTE S2_DFLEx_total=T_L2S2_pix_total/(lx**2) .

COMPUTE S_DFLEx_total=sqrt(S2_DFLEx_total) .

FORMAT S2_pix_total (F8.6) L2S2_pix_total  T_L2S2_pix_total (F10.0) S2_DFLEx_total (F7.5) S_DFLEx_total (F5.3) .

VARIABLE LABELS Nx 'Number in survey in age interval'


  
      S2_pix_total 'Variance of prevalence disability-free'


  
      S2_DFLEx_total 'Variance of DFLEx' 



      S_DFLEx_total 'Standard error of DFLEx' .

SAVE OUTFILE='_____\example6B.sav'


       /* Specify the directory of the output data */

   /KEEP=x agegr lx nLx ex pix Ix pix_total DFLEx_total Nx S2_pix_total L2S2_pix_total T_L2S2_pix_total S2_DFLEx_total S_DFLEx_total /COMPRESSED .

